1000 CLS
1005 REM $Id: BKHCAPT.BAS,v 1.3 2015/04/26 brianh Exp brianh $
1010 REM PREPARE ARRAYS: S$-STATE, C$-CAPITAL, P$-MOST POPULUS CITY, A$-ABBREVIATION
1015 DIM S$(50)
1020 DATA ALABAMA, ALASKA, ARIZONA, ARKANSAS, CALIFORNIA, COLORADO, CONNECTICUT, DELAWARE, FLORIDA, GEORGIA, HAWAII, IDAHO, ILLINOIS, INDIANA, IOWA, KANSAS, KENTUCKY, LOUISIANA, MAINE, MARYLAND, MASSACHUSETTS, MICHIGAN, MINNESOTA, MISSISSIPPI
1025 DATA MISSOURI, MONTANA, NEBRASKA, NEVADA, NEW HAMPSHIRE, NEW JERSEY, NEW MEXICO, NEW YORK, NORTH CAROLINA, NORTH DAKOTA, OHIO, OKLAHOMA, OREGON, PENNSYLVANIA, RHODE ISLAND, SOUTH CAROLINA, SOUTH DAKOTA, TENNESSEE, TEXAS, UTAH, VERMONT, VIRGINIA
1030 DATA WASHINGTON, WEST VIRGINIA, WISCONSIN, WYOMING
1035 FOR X = 1 TO 50
1040 READ S$(X)
1045 NEXT X
1050 DIM C$(50)
1055 DATA MONTGOMERY, JUNEAU, PHOENIX, LITTLE ROCK, SACRAMENTO, DENVER, HARTFORD, DOVER, TALLAHASSEE, ATLANTA, HONOLULU, BOISE, SPRINGFIELD, INDIANAPOLIS, DES MOINES, TOPEKA, FRANKFORT, BATON ROUGE, AUGUSTA, ANNAPOLIS, BOSTON, LANSING, SAINT PAUL
1060 DATA JACKSON, JEFFERSON CITY, HELENA, LINCOLN, CARSON CITY, CONCORD, TRENTON, SANTA FE, ALBANY, RALEIGH, BISMARCK, COLUMBUS, OKLAHOMA CITY, SALEM, HARRISBURG, PROVIDENCE, COLUMBIA, PIERRE, NASHVILLE, AUSTIN, SALT LAKE CITY, MONTPELIER, RICHMOND
1065 DATA OLYMPIA, CHARLESTON, MADISON, CHEYENNE
1070 FOR X = 1 TO 50
1075 READ C$(X)
1080 NEXT X
1085 DIM P$(50)
1090 DATA BIRMINGHAM, ANCHORAGE, PHOENIX, LITTLE ROCK, LOS ANGELES, DENVER, BRIDGEPORT, WILMINGTON, JACKSONVILLE, ATLANTA, HONOLULU, BOISE, CHICAGO, INDIANAPOLIS, DES MOINES, WICHITA, LOUISVILLE, NEW ORLEANS, PORTLAND, BALTIMORE, BOSTON
1095 DATA DETROIT, MINNEAPOLIS, JACKSON, KANSAS CITY, BILLINGS, OMAHA, LAS VEGAS, MACHESTER, NEWARK, ALBUQUERQUE, NEW YORK, CHARLOTTE, FARGO, COLUMBUS, OKLAHOMA CITY, PORTLAND, PHILADELPHIA, PROVIDENCE, COLUMBIA, SIOUX FALLS, MEMPHIS 
1100 DATA HOUSTON, SALT LAKE CITY, BURLINGTON, VIRGINIA BEACH, SEATTLE, CHARLESTON, MILWAUKEE, CHEYENNE
1105 FOR X = 1 TO 50
1110 READ P$(X)
1115 NEXT X
1120 DIM A$(50)
1125 DATA AL, AK, AZ, AR, CA, CO, CT, DE, FL, GA, HI, ID, IL, IN, IA, KS, KY, LA, ME, MD, MA, MI, MN, MS, MO, MT, NE, NV, NH, NJ, NM, NY, NC, ND, OH, OK, OR, PA, RI, SC, SD, TN, TX, UT, VT, VA, WA, WV, WI, WY
1130 FOR X = 1 TO 50
1135 READ A$(X)
1140 NEXT X
1145 PRINT "*** STATE CAPITAL QUIZ ***"
1150 REM RANDOMLY LOOP BETWEEN INDEX 1 AND 50 NOT REPEATING ANY NUMBER
1155 REM X,Y - LOOP INDEX VARIABLES, U - SLOT TO DETERMINE PREVIOUS SELECTIONS
1160 REM U$ - USER ANSWER, E$ - TRY AGAIN, W - COUNT OF CORRECTLY ANSWERED 
1165 W=0
1170 DIM U(50)
1175 FOR X=1 TO 50
1180 Y=RND(50)
1185 IF U(Y)=1 GOTO 1180
1190 U(Y)=1
1195 PRINT  
1200 PRINT "QUESTION"; X; "OF 50"
1205 PRINT "WHAT IS THE CAPITAL OF "; S$(Y)
1210 INPUT U$
1215 IF U$ = C$(Y) THEN GOTO 1245 
1220 PRINT "INCORRECT, DO YOU WANT TO TRY AGAIN (Y/N)"
1225 E$ = INKEY$
1226 IF E$ = "" GOTO 1225
1230 IF E$ = "Y" GOTO 1205
1235 PRINT "THE CORRECT ANSWER WAS "; C$(Y)
1240 GOTO 1255
1245 PRINT "CORRECT, GREAT JOB!"
1250 W=W+1
1255 NEXT X
1260 PRINT
1265 PRINT "YOU ANSWERED"; W; "OUT OF 50 CORRECTLY."
1270 PRINT "THAT IS"; W/50*100; "%"